IBM has made just about everything in free-format RPG truly free-format…except O-specs. But you can print without needing an externally defined printer file.

Instead of adding free-format support for O-specs, IBM expects you to use an externally defined printer file, which can do everything O-specs can. But recently, I wanted to print a simple report and didn't want to create a separate printer file. I remembered reading somewhere about writing to a program describer printer file from a data structure. It turns out to be easy in free-form RPG, with code like this:

    dcl-ds line len(132) end-ds;

    write QPRINT line;

Building the Print Line

But how do you populate the data structure? Google helped me find the original article running around in my memory. It was written by Cletus the Codeslinger way back in 2004. His solution was to create "columns" of data in a data structure. Armed with that suggestion, I tried a test program:

**free

ctl-opt option(*srcstmt) actgrp(*new) main(Prt);

dcl-f   QCUSTCDT Disk extfile('QIWS/QCUSTCDT');

dcl-f   QPRINT printer(132);

dcl-proc Prt;

    dcl-ds line len(132) inz qualified;

        custname    char(20);

        *n          char(1);

        custinit    char(10);

        *n          char(3);

        cusnum      char(6);

    end-ds;

    read QCUSTCDT;

    dow (not %eof(QCUSTCDT));

        line.cusnum = %char(CUSNUM);

        line.custname = LSTNAM;

        line.custinit = INIT;

        write QPRINT line;

        read QCUSTCDT;

    enddo;

    return;

end-proc;

And sure enough, I got a nicely spaced report from file QIWS/QCUSTCDT data:

Figure 1: This report looks the way I hoped it would.

As Cletus pointed out, moving columns around or adding more space between them is remarkably easy by simply redefining the data structure. (This is way easier in a GUI editor than in SEU. So a quick plug for VS Code and the Code for IBM i extension.)

What About Headings?

With data structures, headings are also easy. I inserted these additional lines to define and populate a data structure for the heading:

    dcl-ds head likeds(line);

    head.custname = 'Name';

    head.custinit = 'Initials';

    head.cusnum = 'Number';

    write QPRINT head;

Running the new program, I now have column headings:

Figure 2: Now I have headings too.

So now I had an easy way to print my simple report.

What About Top and Bottom Margins?

But when the report went to more than one page, I was printing on all 66 lines on the page. I needed a way to skip to, for example, line 6 to produce a top margin, and some way to determine whether I was near the bottom of the page before skipping to create a bottom margin.

Bottom of the page is easy: just code an overflow indicator (oflind):

dcl-f   QPRINT printer(132) oflind(*in99);

But when the overflow indicator turns on, how do you get back to the top of the page?

Cletus, of course, knew how to handle new pages: It was right there at the end of his article. Unfortunately, I didn't read that far.

So, in my infinite wisdom, when overflow turned on, I just printed enough blank lines to fill out the current page, and then I printed enough blank lines to produce a suitable top margin. And I had a functional report. But…

What About Overprinting?

Some people like to underscore headings and totals. I was stuck again, since my approach couldn't allow that. Frankly, overprinting was overkill for my simple report, but I'd come this far, so why stop now?

First Character Forms Control (FCFC) came to mind, and Google helped out again. If you are not familiar with FCFC, the first character of the print line controls the spacing. This Wiki article gives a decent overview of FCFC. There's an IBM document here.

I created my own program describe print file with this command:

CRTPRTF FILE(MYPRT) CTLCHAR(*FCFC) CHLVAL((1 (3)))

That means FCFC is in effect, and top of the page is on line 3, controlled by channel 1. Prompt the command and read the help for the CHLVAL parameter. (You can get the same setup with an OVRPRTF command to QPRINT if you don't want an additional print file.)

I made the line length 133 in the RPG to account for the extra control character on the front, and then I did a little coding. First, I defined the FCFC control characters as constants with more meaningful names:

    dcl-c TOP '1';       // Skip to top of page & print

    dcl-c S1  ' ';       // Space 1 line & print

    dcl-c S2  '0';       // Space 2 lines & print

    dcl-c S3  '-';       // Space 3 lines & print

    dcl-c S0  '+';       // Space 0, overprint

Then I defined a data structure "line" for a 133-character line. The first character of the line is the FCFC. I included a 6-character left margin and a field "text" for any situations where I might want to print unstructured text. I overlaid "text" with the column definitions, just two in this case since this is a demo program that prints an increasing number and a timestamp.

    dcl-ds line len(133) inz qualified;

        fcfc     char(1);

        *n       char(6);        // left margin

        text     Char(125);      // Ad-hoc text

        num      char(6)    overlay(text:*next);

        *n       char(6)    overlay(text:*next);

        ts       char(26)   overlay(text:*next);

    end-ds;

Next I defined three heading lines, like the “line” data structure, and populated them, setting the FCFC values and the heading text.

    dcl-ds   head1 likeds(line);

    dcl-ds   head2 likeds(line);

    dcl-ds   head3 likeds(line);

    head1.fcfc = TOP;

    head1.text = 'Sample Report Using Concocted Data';

    head2.fcfc = S2;

    head2.num = 'Number';

    head2.ts = 'Time Stamp';

    head3.fcfc = S0;

    head3.num = *all'_';

    head3.ts = *all'_';

    *in99 = *on;    // First page is always skip

Then a simple loop to write the report and handle overflow:

    for k = 1 to 70;

        if (*in99 = *on);

            *in99 = *off;

            write MYPRT head1;

            write MYPRT head2;

            write MYPRT head3;

        endif;

        evalr line.num = %trim(%char(k));

        line.ts = %char(%timestamp());

        line.fcfc = S1;

        write MYPRT line;

    endfor;

    line.fcfc = S3;

    line.text = '*** End of Report ***';

    write MYPRT line;

And now I have a program that generates a report like this:

Figures 3 and 4: Now this two-page report looks really good.

The Cletus Approach to Headings

My solution turned out to be different from the one Cletus used. He used the PRTCTL parameter on the printer F-spec. The PRTCTL parameter defines a data structure that specifies spacing and skipping for each a line. Like this:

dcl-f   QPRINT printer(132) oflind(*in99) prtctl(pCtl);

dcl-ds  pCtl len(15) qualified inz;

    sp_b4    char(3);   // Space before

    sp_aft   char(3);   // Space after

    sk_b4    char(3);   // Skip to line num before

    sk_aft   char(3);   // Skip to line num after

    linenum  char(3);

This approach gives you a bit more control, and you can do more skipping and spacing before and after like you can do in O-specs. You don't have to create your own FCFC printer file or override QPRINT. I modified my FCFC test program to use this approach, and it came out about 20 lines longer, but that just might be my coding style. For simple reports, I think FCFC printing is easier and quite straightforward.

You can find IBM PRTCTL documentation here.

Conclusion

Maybe report writing is on the wane, being replaced by spreadsheet downloads or JSON micro services accessed from your browser, but if you still need to print from free-format RPG and don't want to create an externally defined print file, you now have two easy alternative options. (And on a side note, qualified data structures in RPG are extremely useful.)

The code for my two test programs can be downloaded from this site. They can also be found in my GitHub repository.

What Next?

Since I was into this, and I also occasionally wish I could print from a CLP program, I'm in the process of writing a general printing program that can be called either from RPG or with a CL command.

Sam Lennon is an analyst, developer, consultant and IBM i geek. He started his programming career in 360 assembly language on IBM mainframes, but moved to the AS400 platform in 1991 and has been an AS400/iSeries/i5/IBM i advocate ever since.