29
Fri, Nov
0 New Articles
  1. You are here:  
  2. Home
  3. Programming
  4. RPG
  5. Tips and Techniques: Delete Old Spool Files

Tips and Techniques: Delete Old Spool Files

RPG
Typography
  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

It's the end of the year, so now is a good time to clean up your DASD. Often, I find that when I create a compiler listing or sample report, I leave the corresponding spool file out there for what seems like forever. So I created the Delete My Old Spool Files (DLTOLDSPLF) command.

The DLTOLDSPLF command allows you to easily clean up older, unneeded spool files. You pass in the number of days old a spool file has to be before it is deleted and optionally a user profile name, and poof, they're gone!

To delete my own spool files that are at least 30 days old, I would run the following command:

DLTOLDSPLF  DAYS(30)

Of course, you should only delete your own user profile's spool files, so the USRPRF parameter defaults to USRPRF(*CURRENT). But because we're programmers, we can, of course, delete almost anything we want (Sarbanes-Oxley, turn your head for a second). To delete all the spool files that are at least 60 days old for the user profile named BOB, you would run the following command:

DLTOLDSPLF  DAYS(60) USRPRF(BOB)

Provided you have regular OS/400 or i5/OS authorization to these spool files, poof, they're gone!

I'm using the CRTSPLLIST() procedure from the xTools *SRVPGM to build the list of spool file entries. If you don't have that service program installed, you can call the QUSLSPL API, the prototype for which is included at the end of this article. Using the CRTSPLLIST procedure reduces the parameters that I need to specify. It also saves space in this newsletter and allows me to publish more powerful code with fewer statements. In a few weeks, I will present the Delete Old IFS Files (DLTOLDIFS) command, which deletes files from a specific directory of the IFS once they become a specified number of days old.

The source code for DLTOLDSPLF is available online, but I have reproduced it here.

The command definition source code for the DLTOLDSPLF command is listed below.

DLTOLDSPLF: CMD        PROMPT('Delete my old spool files')

             /*   Command processing program is: DLTOLDSPLF */

             PARM       KWD(DAYS) TYPE(*UINT2) DFT(14) EXPR(*YES) +
                          PROMPT('Number of days to qualify')
             PARM       KWD(USRPRF) TYPE(*NAME) LEN(10) +
                          DFT(*CURRENT) SPCVAL((*CURRENT)) +
                          EXPR(*YES) PROMPT('User profile')

To view this source member online or to download it directly, follow this link.

The RPG IV source code for the DLTOLDSPLF program is listed below:

H BNDDIR('XTOOLS/RPGLIB' : 'QC2LE')
H  OPTION(*SRCSTMT:*NODEBUGIO)
H  DFTACTGRP(*NO) ACTGRP('XTOOLS')

 *****************************************************
 ** An example program that uses the RPG xTools.    **
 ** ----------------------------------------------- **
 ** Delete Old Spool Files                          **
 *****************************************************

 **  See also...
 **   QCMDSRC(DLTOLDSPLF)


D DltOldSplf      PR
D  nDaysOld                      5U 0 OPTIONS(*NOPASS)
D  szUsrPrf                     10A   OPTIONS(*NOPASS)

D DltOldSplf      PI
D  nDaysOld                      5U 0 OPTIONS(*NOPASS)
D  szUsrPrf                     10A   OPTIONS(*NOPASS)

 /INCLUDE XTOOLS/QCPYSRC,cprotos
 /INCLUDE XTOOLS/QCPYSRC,utils
 /INCLUDE XTOOLS/QCPYSRC,lists


D MySplf          S                   LIKE(RTK_SFL0200)

 **  How long before we delete the SPLF?
D DFTExpired      C                   Const(14)

D szUser          S             10A   Inz(*USER)
D today           S               D   Inz(*SYS)
D crtDate         S               D   DatFmt(*ISO)
D nExpired        S             10I 0
D nDays           S             10I 0
D nSplf           S             10I 0
D nPos            S             10I 0
D I               S             10I 0
D dltsplf         S             64A   Varying

 **  All DLTSPLF commands that are run, are
 **  posted to the joblog as informational messages.
D cmdShell        C                   Const('DLTSPLF FILE(%s) JOB(+
D                                           %s/%s/%s) SPLNBR(%s)')

C                   eval      *INLR = *ON

 **  If the caller passed in the number of days-old to delete,
 **  use that value, otherwise use the default of 14 days.
C                   if        %Parms >= 1
C                   eval      nExpired = nDaysOld
C                   else
C                   eval      nExpired = DFTExpired
C                   endif

 **  If the caller passed in a specific user profile,
 **  use that profile, otherwise use the default *CURRENT.
C                   if        %Parms >= 2
C                   if        szUsrPrf <> *BLANKS
C                              and %subst(szUsrPrf:1:1) <> '*'
C                   eval      szUser   = szUsrPrf
C                   endif
C                   endif

 **  Create a list of spool files for the user profile.
 **  The xTools SPLF0200 format is returned. Note that this format
 **  is a consolidation of the screwy format that IBM created.
 **  On later releases of OS/400, SPLF0300 was added by IBM to do
 **  what is already being accomplished by the SPLF0200 format in xTools.
 **  Since I want this to work on V4R5 and later, I'm using the xTools.

C                   eval      nSplf = CrtSplList('*':'SPLF0200': szUser)
C                   if        nSplf <= 0
C                   callp     WrtJoblog('No spool files found for +
C                                        user %s': szUser)
C                   endif

 **  Iterate through the list of spool file entries that were generated.
 **  If the date the spool file was created is older than our "days old"
 **  setting, then issue a DLTSPLF command for that spool file.
C                   dow       GetNextEntry('*': nPos : mySplf) > 0
C                   eval      RTK_SFL0200 = mySplf
C     *CYMD0        MOVE      TK_QUSDTOPN   CrtDate
C     Today         SubDur    CrtDate       nDays:*DAYS
C                   if        nDays >= nExpired
 **  The xTools' FMTTEXT procedure allows us to easily
 **  create the DLTSPLF command string.
C                   eval      dltsplf = FmtText(cmdShell: TK_QUSSPLFNM :
C                                                 %TRIMR(TK_QUSJOBNBR) :
C                                                 %TRIMR(TK_QUSUSRNAM) :
C                                                 %TRIMR(TK_QUSJOBNAM) :
C                                                  %Char(TK_QUSSPLNBR) )
 **  Log the DLTSPLF command to the joblog before running it.
C                   callp     wrtjoblog(dltsplf)
 **  Delete the spool file.
C                   callp     system(dltsplf)
C                   endif
C                   enddo
 **  ENDPGM:
C                   return

To view this source member online or to download it directly, follow this link.

The prototype for the QUSLSPL API is as follows:

 *********************************************************
 ** E N U M E R A T E   S P O O L  F I L E  N A M E S   L I S T
 *********************************************************
D QUSLSPL         PR                  ExtPgm('QUSLSPL')
D  szUserSpace                  20A   Const
D  Format                        8A   Const
D  UserName                     10A   Const
D  OutQ                         20A   Const
D  FormType                     10A   Const
D  UserData                     10A   Const 
D  apiError                           Like(QUSEC) OPTIONS(*NOPASS)
D  JobID                        26A   Const OPTIONS(*NOPASS)
D  RtnFldKeys                   10I 0 Const OPTIONS(*NOPASS) 

D Dim(24)
D FldKeyCnt 10I 0 Const OPTIONS(*NOPASS)
D ASP 10I 0 Const OPTIONS(*NOPASS)

Bob Cozzi is a programmer/consultant, writer/author, and software developer. His popular RPG xTools add-on subprocedure library for RPG IV is fast becoming a standard with RPG developers. His book The Modern RPG Language has been the most widely used RPG programming book for more than a decade. He, along with others, speaks at and produces the highly popular RPG World conference for RPG programmers.

BOB COZZI

Bob Cozzi is a programmer/consultant, writer/author, and software developer. His popular RPG xTools add-on subprocedure library for RPG IV is fast becoming a standard with RPG developers. His book The Modern RPG Language has been the most widely used RPG programming book for more than a decade. He, along with others, speaks at and produces the highly popular RPG World conference for RPG programmers.

MC Press books written by Robert Cozzi available now on the MC Press Bookstore.

RPG TnT RPG TnT
Get this jam-packed resource of quick, easy-to-implement RPG tips!
List Price $65.00

Now On Sale

The Modern RPG IV Language The Modern RPG IV Language
 Cozzi on everything RPG! What more could you want?
List Price $99.95

Now On Sale
BLOG COMMENTS POWERED BY DISQUS

LATEST COMMENTS

Support MC Press Online

$

Book Reviews

Resource Center

  • SB Profound WC 5536 Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application. You can find Part 1 here. In Part 2 of our free Node.js Webinar Series, Brian May teaches you the different tooling options available for writing code, debugging, and using Git for version control. Brian will briefly discuss the different tools available, and demonstrate his preferred setup for Node development on IBM i or any platform. Attend this webinar to learn:

  • SB Profound WP 5539More than ever, there is a demand for IT to deliver innovation. Your IBM i has been an essential part of your business operations for years. However, your organization may struggle to maintain the current system and implement new projects. The thousands of customers we've worked with and surveyed state that expectations regarding the digital footprint and vision of the company are not aligned with the current IT environment.

  • SB HelpSystems ROBOT Generic IBM announced the E1080 servers using the latest Power10 processor in September 2021. The most powerful processor from IBM to date, Power10 is designed to handle the demands of doing business in today’s high-tech atmosphere, including running cloud applications, supporting big data, and managing AI workloads. But what does Power10 mean for your data center? In this recorded webinar, IBMers Dan Sundt and Dylan Boday join IBM Power Champion Tom Huntington for a discussion on why Power10 technology is the right strategic investment if you run IBM i, AIX, or Linux. In this action-packed hour, Tom will share trends from the IBM i and AIX user communities while Dan and Dylan dive into the tech specs for key hardware, including:

  • Magic MarkTRY the one package that solves all your document design and printing challenges on all your platforms. Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product. Make sure your data survives when catastrophe hits. Request your trial now!  Request Now.

  • SB HelpSystems ROBOT GenericForms of ransomware has been around for over 30 years, and with more and more organizations suffering attacks each year, it continues to endure. What has made ransomware such a durable threat and what is the best way to combat it? In order to prevent ransomware, organizations must first understand how it works.

  • SB HelpSystems ROBOT GenericIT security is a top priority for businesses around the world, but most IBM i pros don’t know where to begin—and most cybersecurity experts don’t know IBM i. In this session, Robin Tatam explores the business impact of lax IBM i security, the top vulnerabilities putting IBM i at risk, and the steps you can take to protect your organization. If you’re looking to avoid unexpected downtime or corrupted data, you don’t want to miss this session.

  • SB HelpSystems ROBOT GenericCan you trust all of your users all of the time? A typical end user receives 16 malicious emails each month, but only 17 percent of these phishing campaigns are reported to IT. Once an attack is underway, most organizations won’t discover the breach until six months later. A staggering amount of damage can occur in that time. Despite these risks, 93 percent of organizations are leaving their IBM i systems vulnerable to cybercrime. In this on-demand webinar, IBM i security experts Robin Tatam and Sandi Moore will reveal:

  • FORTRA Disaster protection is vital to every business. Yet, it often consists of patched together procedures that are prone to error. From automatic backups to data encryption to media management, Robot automates the routine (yet often complex) tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:

  • FORTRAManaging messages on your IBM i can be more than a full-time job if you have to do it manually. Messages need a response and resources must be monitored—often over multiple systems and across platforms. How can you be sure you won’t miss important system events? Automate your message center with the Robot Message Management Solution. Key features include:

  • FORTRAThe thought of printing, distributing, and storing iSeries reports manually may reduce you to tears. Paper and labor costs associated with report generation can spiral out of control. Mountains of paper threaten to swamp your files. Robot automates report bursting, distribution, bundling, and archiving, and offers secure, selective online report viewing. Manage your reports with the Robot Report Management Solution. Key features include:

  • FORTRAFor over 30 years, Robot has been a leader in systems management for IBM i. With batch job creation and scheduling at its core, the Robot Job Scheduling Solution reduces the opportunity for human error and helps you maintain service levels, automating even the biggest, most complex runbooks. Manage your job schedule with the Robot Job Scheduling Solution. Key features include:

  • LANSA Business users want new applications now. Market and regulatory pressures require faster application updates and delivery into production. Your IBM i developers may be approaching retirement, and you see no sure way to fill their positions with experienced developers. In addition, you may be caught between maintaining your existing applications and the uncertainty of moving to something new.

  • LANSAWhen it comes to creating your business applications, there are hundreds of coding platforms and programming languages to choose from. These options range from very complex traditional programming languages to Low-Code platforms where sometimes no traditional coding experience is needed. Download our whitepaper, The Power of Writing Code in a Low-Code Solution, and:

  • LANSASupply Chain is becoming increasingly complex and unpredictable. From raw materials for manufacturing to food supply chains, the journey from source to production to delivery to consumers is marred with inefficiencies, manual processes, shortages, recalls, counterfeits, and scandals. In this webinar, we discuss how:

  • The MC Resource Centers bring you the widest selection of white papers, trial software, and on-demand webcasts for you to choose from. >> Review the list of White Papers, Trial Software or On-Demand Webcast at the MC Press Resource Center. >> Add the items to yru Cart and complet he checkout process and submit

  • Profound Logic Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application.

  • SB Profound WC 5536Join us for this hour-long webcast that will explore:

  • Fortra IT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators with intimate knowledge of the operating system and the applications that run on it is small. This begs the question: How will you manage the platform that supports such a big part of your business? This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn: