The Technical Refresh 7 (TR7) and PTFs are now available.

Last October, IBM announced big changes in free-format RPG IV, to be available in late November. If you are ready to try out the new capabilities of free-format RPG IV, you'll need Technology Refresh 7 (TR7), cumulative PTFs, and PTF SI51337 (which isn't a part of the cumulative package). If you haven't heard about these changes, this article will provide you with a basic idea of most of the changes.

Control (H), File Description (F), Definition (D), and Procedure (P) specifications can now be done in free-format. And now there's no longer the need for the /Free or /End-free compiler directives. Is there anything left that's fixed-format? The answer is yes: Input (I) and Output (O) specs must still be coded in fixed-format, but many of us have done without these for a while. The exception would be those who prefer program-described printing.

Control Specifications

The control specifications were nearly free-format already, but now they're officially free-format. Here's an example of an H-specification and its free-format equivalent:

H option(*srcstmt:*nodebugio) dftactgrp(*no) actgrp('QILE')

H bnddir('XYIGNM':'TOOLS')

Ctl-Opt option(*srcstmt:*nodebugio) dftactgrp(*no) actgrp('QILE')

bnddir('XYIGNM':'TOOLS');

The free-format version must be placed in the usual free-format locations, between 8 and 80, and end with a semicolon. Instead of the H in 6, start the control statement with Ctl-Opt. Otherwise, the various keywords and values stay the same as they were. New in this format: If you name an activation group, binding directory, or storage model, you can omit the dftactgrp(*no) parameter.

File Specifications

File descriptions have changed a lot for free-format. First, files are declared, similar to CL programs, and the device now defaults to Disk (database file). Here's an example:

Dcl-f PRMaster;

The line above defines the use of file PRMaster, on Disk, with default file type of Input. You can also specify the word disk on the statement (after the file name) if you want, perhaps to better clarify the code. Additional examples follow:

Dcl-f Orders usage(*update) keyed;

The line above defines the file Orders, on Disk, to be updated. The parameter keyed means that the records can be accessed by key.

Dcl-f PRCheck printer oflind(overflow);

The line above defines printer file PRCheck. The parameter "printer" tells the compiler it's a printer device, and the oflind parameter and its value are entered similar to file keywords used by the fixed-format scheme.

In the second example above, the parameter usage was used with value *Update. There are four possible values for the usage parameter: *Input, *Output, *Update, and *Delete. *Input is the default for disk files, *Output is the default for printer files, and (*Input:*Output) would be used for workstation files. In fixed-format, file type U (for update) included the delete function. In this new free-format, it doesn't. To delete records in the program, *Delete must be specified in the usage parameter.

There are many other parameters needed for program-described files that will not be covered in this article.

Definition Specifications

Once again, the Dcl prefix is used for defining (now declaring) items that were previously entered in D-specs. The letter that follows the dash corresponds to the declaration type used in fixed-format. I'll show a few examples below, but I won't be able to provide an exhaustive list of all of the new functionality. Here's my first example:

Dcl-S SaveCustNo Like(CMCustNo);

The line above defines work field SaveCustNo like previously defined field CMCustNo.

Dcl-c twenty_one 21;

The line above defines named constant twenty_one with decimal value 21.

Dcl-DS DateDS;

   Date8 zoned(8:0);

   CC   zoned(2:0) overlay(Date8);

   YY   zoned(2:0) overlay(Date8:*next);

   MMDD zoned(4:0) overlay(Date8:*next);

End-DS DateDS;

The above data structure DateDS has subfields that break down a date. The new item we must now do is to add an End-DS line to our data structures.

Dcl-PR EXPGM;

   Parm1 char(10);

   Parm2 packed(2:0);

End-PR;

The above prototype EXPGM specifies calling program EXPGM as an external program (the default). The two parameter definitions are specified. The End-PR line must now be added.

Dcl-PI EXPGM;

   Name char(10);

   Number packed(2:0);

End-PI;

The above example shows the procedure interface inside program EXPGM.

All previously used keywords used in prototypes and procedure interfaces are still available. One other thing: if you choose a parameter name that's the same name as an op-code, such as Select, then you must specify the prefix dcl-parm just before the parameter name.

Procedure Specifications

Procedure specifications are begun with a Dcl-Proc and end with an End-Proc. All previously described statements for files, definitions, and calculations are performed within those two lines. The return value is defined after the DCL-Proc with the Dcl-PI and End-PI statements. The following is an example of a subprocedure definition.

Dcl-Proc AddParms export;

   Dcl-PI *N packed(9:2); // No need for a name, so *N is used

Add1 packed(5:2);

Add2 packed(5;2);

   End-PI;

   Dcl-S Answer packed(9:2);

 Return Add1 + Add2;

End-Proc AddParms;

Final Comments

I would be remiss if I didn't mention a couple more items. First, the file and definition declarations can be interspersed. This means that without some coding standards, the file and definitions section of a program could turn out to be a conglomeration, meaning a really bad mess. Another item: since there are no /Free or /End-free requirements, some programmers may fall back to using fixed-format operations within a predominately free-format section of code rather than figure out a more structured method. I am mainly referring to the use of the Goto operation. Other more difficult conversion situations are "suspect" too, such as MOVEAs. The resulting code would be a mix of old and new. I leave it to the various RPG blogs to see what you think of this. If you have an opinion, perhaps you would like to post it into the forums associated with this article.

Again, this "tip" is not intended to be a thorough discourse on the new free-format coding options but rather an introduction to this new free-format style. When you get a chance, try it!

Jim Martin holds a BS degree in mathematics and an MS in computer science. For 26 years, he was employed by IBM, where he wrote RPG applications for customers and worked in the programming laboratory as a programmer on portions of CPF and the OS/400 operating system. After leaving IBM, Jim took post-graduate work in computer science and performed RPG training. He is an IBM-certified RPG IV developer and author of multiple bestselling editions of Free-Format RPG IV, which, since the book's initial publication in 2005, have taught thousands of RPG IV programmers how to be successful with the free-format coding style.

---

MC Press books written by Jim Martin available now on the MC Press Bookstore.

		Free-Format RPG IV: Third Edition Improve productivity, readability, and program maintenance with the free-format style of programming in RPG IV. List Price $59.95 Now On Sale
		Free-Format RPG IV: Second Edition >Make the transition from coding in fixed-format RPG to free format. List Price $59.95 Now On Sale
		Functions in Free-Format RPG IV Here’s the ultimate guide to writing RPG IV programs with functions in the free-format style. List Price $59.95 Now On Sale

Also Read

H and F Position-less Specs

Practical RPG: AI and IBM i

Programming in ILE RPG - Defining Standalone Variables & Assigning Initial Values to Data