02
Sat, Nov
2 New Articles
  1. You are here:  
  2. Home
  3. Programming
  4. RPG
  5. TechTip: Elapsed Time Function

TechTip: Elapsed Time Function

RPG
Typography
  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

If you're creating an application that has to calculate elapsed time based on a start and end time, you know what a challenging task this can be. Even with many of the date and time RPG op codes, this can often involve incorporating some ugly code into your application. To solve this problem, you can use the CalcElapsed ILE RPG user-defined function. I'll show you how this function works, how to create it, and how to incorporate it into your applications.

As you can see below in the source for this function's prototype, this function accepts five parameters. The first two parameters, start date and end date, are supplied as a date (D) data type. The next two parameters, start time and end time, are supplied as a time (T) data type. The fifth parameter is used to identify the data to be returned by the function.

     D CalcElapsed     PR            14  6         
     D  FromDate                       D   VALUE DATFMT(*ISO)
     D  ToDate                         D   VALUE DATFMT(*ISO)
     D  FromTime                       T   VALUE
     D  ToTime                         T   VALUE     
     D  Format                        1A   VALUE    


The value returned by the function will be a 14-digit number with six decimal places. The actual value returned depends on the value of the fifth parameter. If D is specified, the value returned represents the number of days. The decimal places represent the minutes and seconds as a decimal portion of a day; for example, 12 hours would be .5 days. If H is specified, the elapsed time is returned in hours. Again, the decimal portion would represent the minutes as a portion of an hour. The final option, L, returns a value whereby everything to the left of the decimal represents years, months, and days, and the numbers to the right of the decimal point represent hours minutes and seconds (yyyymmdd.hhmnss). For example, an elapsed time of 10 years, 3 months, 2 days, 5 hours and 15 minutes would be returned as 00100302.051500. The source for the CalcElapsed function itself is shown below.

 HDATFMT(*ISO) NOMAIN     
  *===============================================================  
  * Compile Command  
  *
  * Create Commands: CRTRPGMOD MODULE(library/CALCELAPSD)  
  *                            SRCFILE(library/QRPGLESRC)  
  *         
  *===============================================================  
 D/COPY QRPGLESRC,calcelappr   
 D Elapsed         S             14  6 
 D Elapsd2         S             15  0 
 D FrTimeSt        S             30A 
 D ToTimeSt        S             30A  
 D ZeroTime        S               Z   
 D EndStmp         S               Z   
 P CalcElapsed     B                   EXPORT  
 D CalcElapsed     PI            14  6    
 D  FromDate                       D   VALUE DATFMT(*ISO) 
 D  ToDate                         D   VALUE DATFMT(*ISO)  
 D  FromTime                       T   VALUE   
 D  ToTime                         T   VALUE    
 D  Format                        1A   VALUE   
  /Free                                
     FrTimeSt = %Char(FromDate) + '-' + %Char(FromTime) + '.00000'; 
     ToTimeSt = %Char(ToDate) + '-' + %Char(ToTime) + '.00000';  
   Select;   
   When Format='D'; 
        Elapsed=%Diff(%TimeStamp(ToTimeSt: *ISO):  
                %TimeStamp(FrTimeSt:*ISO): *SECONDS)/86400;  
   When Format='H';        
        Elapsed=%Diff(%TimeStamp(ToTimeSt: *ISO):  
                 %TimeStamp(FrTimeSt:*ISO): *SECONDS)/3600; 
   When Format='L';     
        Elapsd2=%Diff(%TimeStamp(ToTimeSt: *ISO):  
                %TimeStamp(FrTimeSt:*ISO): *SECONDS);  
        ZeroTime=*Loval;    
        EndStmp=ZeroTime + %Seconds(Elapsd2);  
        Elapsed=(%Subdt(EndStmp:*YEARS)-1)*10000;   
        Elapsed=Elapsed+(%Subdt(EndStmp:*MONTHS)-1)*100;   
        Elapsed=Elapsed+(%Subdt(EndStmp:*DAYS)-1);  
        Elapsed=Elapsed+%Subdt(EndStmp:*HOURS)*.01; 
        Elapsed=Elapsed+%Subdt(EndStmp:*MINUTES)*.0001;   
        Elapsed=Elapsed+%Subdt(EndStmp:*SECONDS)*.000001;  
   EndSl;        
   Return Elapsed; 
  /End-Free    
 P CalcElapsed     E     


This function takes the supplied date and time values and converts them to a Timestamp field. The %Diff ILE RPG function calculates the difference between the two timestamp values. This %Diff function can be used with two date fields, two time fields, two timestamp fields, a date field and a timestamp field, or a time field and timestamp field. This function is used as follows:

    Diff=%Diff(StartDate: EndDate: *DAYS)


This example would calculate the difference between the two supplied dates and return a value that represents the number of days between the two dates. In the CalcElapsed function, we use the *SECONDS option to calculate seconds between the two dates. Depending on the value of the Format parameter, this value will be divided by either 86,400 (the number of seconds in a day) when the format is D or 3,600 (the number of seconds in an hour) when the format is H. If the format is L, the calculation is a little more complicated. In this case, we need to determine the duration as a value of years, months, days, hours, minutes, and seconds. To do this, we again use the %DIFF function to determine the duration in the lowest level used by the application, which is seconds. Next, we add this value to a timestamp field that has been initialized to *LOVAL. We add the elapsed seconds field value using the %SECONDS BIF, which converts a numeric value to a format that can be added to a date, time, or timestamp field. This will result in a date that has been increased by the number of seconds specified. The resulting value is then divided into the required date and time pieces, which are then reassembled in a way that results in the value being returned as yyyymmdd.hhmnss.

Below is the source for a small RPG application that shows how to incorporate this function into your applications.


HDATFMT(*MDY)
D/COPY QRPGLESRC,calcelappr 
D  FromDate       S               D   DATFMT(*ISO)   
D  ToDate         S               D   DATFMT(*ISO) 
D  FromTime       S               T             
D  ToTime         S               T             
D Difference      S             30A               
C     *ENTRY        PLIST                                              
C                   PARM                    FDate             6  
C                   PARM                    TDate             6   
C                   PARM                    FTime             6   
C                   PARM                    TTime             6  
C                   PARM                    Fmt               1  
C     *MDY0         Move      FDate         FromDate    
C     *MDY0         Move      TDate         ToDate        
C     *HMS0         Move      FTime         FromTime      
C     *HMS0         Move      TTime         ToTime        
C                   Eval      Difference=%EDITC(CalcElapsed(FromDate: 
C                             ToDate:FromTime:ToTime:Fmt): 'M')   
C     Difference    Dsply                                 
C                   Return                                



This program accepts the same five parameters required by our function, except that the date and time values are supplied through an alpha field rather than through a date or time field. This program converts the values provided to date and time values and uses the Eval op code to access the CalcElapsed function for the supplied dates and times. The value returned by the function is edited using the %EDITC function. The resulting value is displayed to the workstation that executes the application.

Creating and incorporating the function into an application is a two-step process. First, you must create the RPG module for the function itself. This is done using the Create RPG Module (CRTRPGMOD) command shown below:

CRTRPGMOD MODULE(library/CALCELAPSD) SRCFILE(library/QRPGLESRC) 


In this example, library should be replaced with our source and/or program library. Next, we have to create the module for our test application. We again use the CRTRPGMOD command to do this:

CRTRPGMOD MODULE(library/TESTELAPSD) SRCFILE(library/QRPGLESRC) 


Once the two modules have been created, we can bind them together using the Create Program (CRTPGM) command:

CRTPGM PGM(MFAUST/TESTELAPSD) MODULE(MFAUST/TESTELAPDS MFAUST/CALCELAPSD)     


The resulting program would be called as shown below:

CALL PGM(TESTELAPSD) PARM('010401' '011502' '084515' '073000' 'L')          


This example is passing a start time and date of 8:45:14 a.m. on January 4, 2001, and an ending time and date of 7:30:00 a.m. on January 15, 2002. Below is a sample of the output displayed when this program is called. (Click image to enlarge.)

http://www.mcpressonline.com/articles/images/2002/elapsedt[1]V500.png

The value shown indicates a difference of 1 year, 10 days, 22 hours, 44 minutes, and 45 seconds from the start to the end.

Your specific needs may require modifications to this function. Maybe you need the option to get to duration in months or even weeks. Either of these could easily be added to our function by simple inserting some extra options for our Format value within the SELECT group. In any case, this function can help you save time. And now you can calculate just how much!

Mike Faust is MIS Manager for The Lehigh Group in Macungie, PA. Mike is also the author of The iSeries and AS400 Programmer's Guide to Cool Things from MC Press. You can contact Mike at This email address is being protected from spambots. You need JavaScript enabled to view it..

Mike Faust

Mike Faust is a senior consultant/analyst for Retail Technologies Corporation in Orlando, Florida. Mike is also the author of the books Active Server Pages Primer, The iSeries and AS/400 Programmer's Guide to Cool Things, JavaScript for the Business Developer, and SQL Built-in Functions and Stored Procedures. You can contact Mike at This email address is being protected from spambots. You need JavaScript enabled to view it..

MC Press books written by Mike Faust available now on the MC Press Bookstore.

Active Server Pages Primer Active Server Pages Primer
Learn how to make the most of ASP while creating a fully functional ASP "shopping cart" application.
List Price $79.00

Now On Sale

JavaScript for the Business Developer JavaScript for the Business Developer
Learn how JavaScript can help you create dynamic business applications with Web browser interfaces.
List Price $44.95

Now On Sale
SQL Built-in Functions and Stored Procedures SQL Built-in Functions and Stored Procedures
Unleash the full power of SQL with these highly useful tools.
List Price $49.95

Now On Sale
BLOG COMMENTS POWERED BY DISQUS

LATEST COMMENTS

Support MC Press Online

$

Book Reviews

Resource Center

  • SB Profound WC 5536 Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application. You can find Part 1 here. In Part 2 of our free Node.js Webinar Series, Brian May teaches you the different tooling options available for writing code, debugging, and using Git for version control. Brian will briefly discuss the different tools available, and demonstrate his preferred setup for Node development on IBM i or any platform. Attend this webinar to learn:

  • SB Profound WP 5539More than ever, there is a demand for IT to deliver innovation. Your IBM i has been an essential part of your business operations for years. However, your organization may struggle to maintain the current system and implement new projects. The thousands of customers we've worked with and surveyed state that expectations regarding the digital footprint and vision of the company are not aligned with the current IT environment.

  • SB HelpSystems ROBOT Generic IBM announced the E1080 servers using the latest Power10 processor in September 2021. The most powerful processor from IBM to date, Power10 is designed to handle the demands of doing business in today’s high-tech atmosphere, including running cloud applications, supporting big data, and managing AI workloads. But what does Power10 mean for your data center? In this recorded webinar, IBMers Dan Sundt and Dylan Boday join IBM Power Champion Tom Huntington for a discussion on why Power10 technology is the right strategic investment if you run IBM i, AIX, or Linux. In this action-packed hour, Tom will share trends from the IBM i and AIX user communities while Dan and Dylan dive into the tech specs for key hardware, including:

  • Magic MarkTRY the one package that solves all your document design and printing challenges on all your platforms. Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product. Make sure your data survives when catastrophe hits. Request your trial now!  Request Now.

  • SB HelpSystems ROBOT GenericForms of ransomware has been around for over 30 years, and with more and more organizations suffering attacks each year, it continues to endure. What has made ransomware such a durable threat and what is the best way to combat it? In order to prevent ransomware, organizations must first understand how it works.

  • SB HelpSystems ROBOT GenericIT security is a top priority for businesses around the world, but most IBM i pros don’t know where to begin—and most cybersecurity experts don’t know IBM i. In this session, Robin Tatam explores the business impact of lax IBM i security, the top vulnerabilities putting IBM i at risk, and the steps you can take to protect your organization. If you’re looking to avoid unexpected downtime or corrupted data, you don’t want to miss this session.

  • SB HelpSystems ROBOT GenericCan you trust all of your users all of the time? A typical end user receives 16 malicious emails each month, but only 17 percent of these phishing campaigns are reported to IT. Once an attack is underway, most organizations won’t discover the breach until six months later. A staggering amount of damage can occur in that time. Despite these risks, 93 percent of organizations are leaving their IBM i systems vulnerable to cybercrime. In this on-demand webinar, IBM i security experts Robin Tatam and Sandi Moore will reveal:

  • FORTRA Disaster protection is vital to every business. Yet, it often consists of patched together procedures that are prone to error. From automatic backups to data encryption to media management, Robot automates the routine (yet often complex) tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:

  • FORTRAManaging messages on your IBM i can be more than a full-time job if you have to do it manually. Messages need a response and resources must be monitored—often over multiple systems and across platforms. How can you be sure you won’t miss important system events? Automate your message center with the Robot Message Management Solution. Key features include:

  • FORTRAThe thought of printing, distributing, and storing iSeries reports manually may reduce you to tears. Paper and labor costs associated with report generation can spiral out of control. Mountains of paper threaten to swamp your files. Robot automates report bursting, distribution, bundling, and archiving, and offers secure, selective online report viewing. Manage your reports with the Robot Report Management Solution. Key features include:

  • FORTRAFor over 30 years, Robot has been a leader in systems management for IBM i. With batch job creation and scheduling at its core, the Robot Job Scheduling Solution reduces the opportunity for human error and helps you maintain service levels, automating even the biggest, most complex runbooks. Manage your job schedule with the Robot Job Scheduling Solution. Key features include:

  • LANSA Business users want new applications now. Market and regulatory pressures require faster application updates and delivery into production. Your IBM i developers may be approaching retirement, and you see no sure way to fill their positions with experienced developers. In addition, you may be caught between maintaining your existing applications and the uncertainty of moving to something new.

  • LANSAWhen it comes to creating your business applications, there are hundreds of coding platforms and programming languages to choose from. These options range from very complex traditional programming languages to Low-Code platforms where sometimes no traditional coding experience is needed. Download our whitepaper, The Power of Writing Code in a Low-Code Solution, and:

  • LANSASupply Chain is becoming increasingly complex and unpredictable. From raw materials for manufacturing to food supply chains, the journey from source to production to delivery to consumers is marred with inefficiencies, manual processes, shortages, recalls, counterfeits, and scandals. In this webinar, we discuss how:

  • The MC Resource Centers bring you the widest selection of white papers, trial software, and on-demand webcasts for you to choose from. >> Review the list of White Papers, Trial Software or On-Demand Webcast at the MC Press Resource Center. >> Add the items to yru Cart and complet he checkout process and submit

  • Profound Logic Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application.

  • SB Profound WC 5536Join us for this hour-long webcast that will explore:

  • Fortra IT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators with intimate knowledge of the operating system and the applications that run on it is small. This begs the question: How will you manage the platform that supports such a big part of your business? This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn: