This article introduces a feature that's been around for some time but that you might not have gotten to know just yet.

This article continues the exploration of procedures, but it does so by taking a little segue into the topic of variable-length fields. With the possible exception of prototypes and procedures themselves, variable-length fields may be one of the most productive additions to the RPG language. If you haven't used variable-length fields, you're in for a treat. Even if you have, you may want to skim through this article anyway just to see how I'm using them.

Variable-Length Fields

Just to set the stage, this article is a continuation of the articles I've written on prototypes. In the first article, I showed you how to use a prototype to replace the PLIST in your programs, and in the second article, I explained how to replace a subroutine with a subprocedure. In the next (last) article on this topic, I'll show you how to really take advantage of some of the benefits of procedures to significantly reduce your code. But before we get there, I need to take you on a little bit of a side trip that explains how to implement variable-length fields using the VARYING keyword.

VARYING is not technically an ILE capability; it's available in RPG IV for ILE and non-ILE programs alike and has been around since V4 of the operating system (that's what makes this article a side trip and not really about procedures at all). However, since so much RPG programming deals with legacy data with fixed-length fields, many of us never had a good reason to use varying-length fields.

However, in the brave new world of stream files, Web pages, XML, and CGI, we RPG programmers find ourselves doing a lot more string manipulation, and code that we used to do with laborious array processing is now done much more easily using variable-length fields.

Meet the Old Program

Let me re-introduce my example program as it stood at the end of the last article:

A h option(*srcstmt: *nodebugio) dftactgrp(*no) actgrp(*new)

B d ShowData        pr                  extpgm('PRO1SND')

B d   Data                       512a

C d TagThis         pr

C d   Tag                         10a

C d   Value                       80a

C d   TaggedValue                128a

D d ATag            s             10a

D d AValue          s             80a

D d ATaggedValue    s            128a

E d ABuffer         s            512a

   /free

F   aTag = 'FIELD1';

F   aValue = 'Field 1 Value';

F   TagThis( aTag: aValue: aTaggedValue);

F   aBuffer = aTaggedValue;

G   aTag = 'FIELD2';

G   aValue = 'Field 2 Value';

G   TagThis( aTag: aValue: aTaggedValue);

G   aBuffer = %trim(aBuffer) + aTaggedValue;

H   ShowData( aBuffer);

H   *inlr = *on;

   /end-free

I p TagThis         b

I d                 pi

I d   Tag                         10a

I d   Value                       80a

I d   TaggedValue                128a

I  /free

I   TaggedValue = '<' + %trim(Tag) + '>' +

I                 %trim(Value) +

I                 '</' + %trim(Tag) + '>';

I  /end-free

I    p                 e                 

A: My standard header specification for ILE programs.

B: A prototype for the PRO1SND program (this sends the value to the user in a message).

C: This is the internal prototype for the TagThis subprocedure. It formally declares the parameters that will be passed.

D and E: My temporary variables. The first three are used to communicate with the TagThis subprocedure, while the other (aBuffer) is used to send the data to PRO1SND.

F: and G: These are the calls to TagThis. I pass the tag and value to TagThis, and it creates a tagged value. In these two sections, I stuff the values into aBuffer. Note that on the second call I have to trim aBuffer and append the second value.

H: Here I send the formatted data to the PRO1SND program to display it to the end user; then I set on *INLR to end the program.

I: TagThis creates the tagged value. It takes the first two fields and, with a lot of trimming, creates a tagged value of the format <TAG>VALUE</TAG>.

Yes, the program is simple. It doesn't use array processing; RPG IV gives us the %trim built-in function. But even so, the code is still more complicated than it needs to be (and is potentially a lot less efficient as well).

VARYING Is Very Nice

The VARYING keyword is the key addition to our little program. As I said earlier, variable-length fields are not particularly new, but to paraphrase, if you haven't used them, they're new to you! So let me present them in brief here. The idea is simple: whereas traditional character fields in RPG have a fixed length, variable-length fields have a maximum length, but they also have an "active" length that is used to indicate the current amount of data in the field. Without going into too much detail, this length is implemented as a counter that specifies how many bytes of the field actually have data. A length of zero means the field has no data, and the maximum value of the length is the size of the field. So the length of a 128-byte variable-length field can be between 0 and 128.

What does this feature buy you? Well, most notably, having a length allows you to concatenate fields without using the %trim BIF. If you set a varying-length field to the value 'ABC' and then concatenate it with another varying-length field containing 'XYZ', your result will always be 'ABCXYZ', regardless of the lengths of the two fields (assuming of course that both have a maximum length of at least three). Contrast this with setting two five-character, fixed-length fields to 'ABC' and 'XYZ', respectively, and then concatenating them: you get 'ABCbbXYZbb', where 'b' represents a blank.

That's why the original program above has several calls to the %trim BIF; these allow us to get rid of trailing (and leading) white space. But with varying, that goes away. Take a look at the new version:

A h option(*srcstmt: *nodebugio) dftactgrp(*no) actgrp(*new) 

B d ShowData        pr                  extpgm('PRO1SND')    

B d   Data                       512a                        

C d TagThis         pr                                       

C d   Tag                         10a   varying               

C d   Value                       80a   varying              

C d   TaggedValue                128a   varying              

D d aTag            s             10a   varying              

D d aValue          s             80a   varying              

D d aTaggedValue    s            128a   varying              

E d aBuffer         s            512a   varying              

E d OutBuffer       s            512a                        

   /free                                                     

F   aTag = 'FIELD1';                                         

F   aValue = 'Field 1 Value';                                

F   TagThis( aTag: aValue: aTaggedValue);                    

F   aBuffer = aTaggedValue;                                  

G   aTag = 'FIELD2';                                         

G   aValue = 'Field 2 Value';                                

G   TagThis( aTag: aValue: aTaggedValue);                    

G   aBuffer += aTaggedValue;                                 

H   OutBuffer = aBuffer;                                     

H   ShowData( OutBuffer);                                    

H   *inlr = *on;                                              

   /end-free                                                 

I p TagThis         b                                        

I d                 pi                                        

I d   Tag                         10a   varying              

I d   Value                       80a   varying              

I d   TaggedValue                128a   varying              

I  /free                                                      

I   TaggedValue = '<' + Tag + '>' + Value + '</' + Tag + '>';

I  /end-free                                                 

I p                 e                                        

A and B: They don't change.

C: The prototype for the internal TagThis subprocedure specifies the VARYING keyword for the parameters, identifying them as variable-length fields.

D: All the temporary variables use VARYING as well.

E: Note that I've had to add an additional field, OutBuffer. That's because the PRO1SND program is expecting a traditional fixed-length field. You can't send a varying-length field when a fixed-length field is expected and vice versa. Well, not yet anyway...

F: and G: These stay almost exactly the same, except for the last line, where I am able to concatenate aTaggedValue onto aBuffer using the '+=' operator. Very simple, no trimming necessary.

H: Here's the only additional work required. I have to convert the variable-length field to a fixed-length field. It's pretty easy; just assign the value. RPG will automatically pad the field with blanks. I then pass the fixed-length field to the called program.

I: This is the biggest change. Note that I don't have to bother with trimming the parameters. Compare this with the first listing, where I have to trim the tag (twice) and the value.

What's the Benefit?

The benefits of simpler code are self-evident. I can remove all calls to %trim, and concatenating the variable-length fields is a lot simpler. However, the real benefit comes when you begin to take advantage of ILE to modularize your code. Modularization requires generic routines, and one of the hardest parts of writing a generic routine is defining one-size-fits-all parameters. If you make the parameters too short, you eventually overrun them and have to make them bigger, which requires updating every program that calls the procedure. If you make them too long, however, you end up passing around a lot of extra data, and processing a lot as well. Having to trim a 64K field every time you use it is not particularly efficient.

For generic routines, the performance benefits of varying-length fields can be substantial, especially when the parameters are long. Since the calling program effectively passes in the actual amount of data in the buffer, you can use really long parameters without nearly as much overhead. It's not a silver bullet; there's a careful balance that must be established between variable-length fields, maximum field size, and the CONST keyword. But that's another topic for another day.

Joe Pluta is the founder and chief architect of Pluta Brothers Design, Inc. He has been extending the IBM midrange since the days of the IBM System/3. Joe uses WebSphere extensively, especially as the base for PSC/400, the only product that can move your legacy systems to the Web using simple green-screen commands. He has written several books, including Developing Web 2.0 Applications with EGL for IBM i, E-Deployment: The Fastest Path to the Web, Eclipse: Step by Step, and WDSC: Step by Step. Joe performs onsite mentoring and speaks at user groups around the country. You can reach him at This email address is being protected from spambots. You need JavaScript enabled to view it..

---

MC Press books written by Joe Pluta available now on the MC Press Bookstore.

		Developing Web 2.0 Applications with EGL for IBM i Joe Pluta introduces you to EGL Rich UI and IBM’s Rational Developer for the IBM i platform. List Price $39.95 Now On Sale
		WDSC: Step by Step Discover incredibly powerful WDSC with this easy-to-understand yet thorough introduction. List Price $74.95 Now On Sale
		Eclipse: Step by Step Quickly get up to speed and productivity using Eclipse. List Price $59.00 Now On Sale

Also Read

Programming in ILE RPG - Defining Data Structures, Part I

H and F Position-less Specs

Practical RPG: AI and IBM i