V4R4 has been out for a few months, and some of you may have installed it already or plan

to install it soon. If your shop uses RPG, now is a good time to learn about the V4R4 enhancements to the RPG IV compiler. IBM did not add a tremendous amount to the compiler this time, but what’s there is good. By supporting new data types, RPG continues to move closer to the networked world, which is the present and future of information processing. I’m glad that even more RPG can now be written in a free-format way. Of course, all the old stuff is still there, including the cycle, my favorite feature of the language.

New Op Codes

The latest version of RPG includes new op codes that I’m going to share with you. I’ll begin with one I’ve wanted for years: LEAVESR.

LEAVESR exits subroutines. It’s like a GOTO that branches to the ENDSR statement. Even though I’ve avoided GOTO for years, I’ve never minded using it to exit subroutines, but I no longer have to do that. With LEAVESR, maybe my code can finally become GOTO-free.

FOR and ENDFOR

The FOR op code is a free-format version of the RPG DO op code. That is, it’s a looping structure governed by a control variable. ENDFOR (or END) marks the end of the body of the loop. FOR differs from DO in that the control variable is required, not optional.

Like RPG DO, FOR initializes the control variable before making its first pass through the body of the loop. Before FOR begins each subsequent pass, it adds an increment to the control variable. It continues to loop until the control variable exceeds a limit. For the control variable to exceed a limit means that the control variable becomes greater than the limit if the control variable increases in value with each iteration. However, if the control variable decreases with each iteration, the increment is subtracted from the control variable. To exceed then means that the control variable becomes less than the limit.

LEAVESR

(I suppose the increment should really be called a “decrement” in that case, but the ILE RPG for AS/400 Reference does not refer to it that way.)

The syntax of FOR is as follows:

FOR control {= initial}

{BY increment}

{TO/DOWNTO limit}

The extended factor 2 begins with the control variable. If specified, the initial value follows, preceded by an equal sign (=). The remaining portions, the increment and limit, follow and can be specified in either order. The increment is preceded by the word BY, and the limit is preceded by either TO or DOWNTO. If TO is used, the increment is added to the control variable, making the control variable ascend in value with each iteration. If DOWNTO is used, the increment is subtracted from the control variable, making the control variable descend with each iteration. Study the examples in Figure 1 to get a better idea of how FOR works.

A word of caution: Be sure that the control variable is large enough to contain not only the initial and limit values, but also the limit value plus (or minus, for DOWNTO loops) the increment. For example, the code in Figure 2 executes three times, with control variable Ndx assuming values of 7, 4, and 1, but fails between the third and fourth iterations because the control variable Ndx decrements from 1 to -2, which doesn’t fit inside an unsigned variable. In the same way, a packed decimal control variable that ranges from 1 to 999 should be at least four digits long to accommodate a terminal test value of
1000.

The other new op code is EVALR (Evaluate expression/Right-adjust). This op code works like the EVAL op code except that the result is right-adjusted. EVALR is valid only for fixed-length character or graphic data. For numeric data, you must continue to use EVAL.

Figure 3 contains a snippet of code that uses EVALR. In this excerpt, two EVALR commands place an edited, right-justified numeric value into variable COLUMN2, resulting in the numbers’ proper alignment on subsequent printings of PRINTLINE.

New Data Types

Those who have to communicate with the outside world may jump for joy at this news. RPG now supports 1-byte and 8-byte integer and unsigned integer data types. It defines 1- byte fields with a length of 3 and 8-byte fields with a length of 20. Those who love decimal arithmetic (like me, I add unashamedly) probably won’t get overly excited about this, but those who must make RPG communicate with other languages, especially C, may feel otherwise. Figure 4 lists all the integer and unsigned types now available in RPG.

RPG also now supports Unicode, officially known as Universal Character Set Version 2 (UCS-2). Like EBCDIC and ASCII, Unicode defines each character as a specific pattern of bits but differs from those two encoding schemes in that it stores a character in 16 bits, rather than 8 bits. Unicode supports national languages and is especially important in Java applications.

To define a Unicode field, use data type C in column 40 of the D-specs. In columns 33 through 39, code the length of the Unicode field in characters, not in bytes. You can also code the C data type in the data format entry of input and output specs.

Use the new %UCS2 built-in function to convert other types of data to Unicode. This function accepts either one or two parameters. The first is a variable or constant to be converted to Unicode, and the second parameter, CCSID, is optional and defaults to
13488.

EVALR

The graphic data type for double-byte character set languages is not new, but the %GRAPHIC function is. This function converts data of other types to the graphic type.

New Initialization Values

The INZ keyword in the D-specs allows two new special initialization values. INZ(*USER) initializes a field to the user ID of the current user, and you use INZ(*EXTDFT) with externally described data structures. INZ(*EXTDFT) tells RPG to initialize a data structure subfield to the default value defined in the file DDS. For example, notice the DDS in Figure 5. The CLASS field has a default value of R. When this file describes a data structure, as in Figure 6, the CLASS subfield is initialized to R.

Operational Functions? Functional Operations?

IBM continues to implement op codes as built-in functions. The %XFOOT (cross-foot) function, like the XFOOT op code, sums the elements of an array. Similarly, the %DIV and %REM functions correspond roughly to the DIV and MVR op codes. I say “roughly” because there is a great difference: %DIV and %REM work only with whole numbers.

%DIV divides one whole number by another and returns the whole number portion of the quotient, whereas %REM also divides one whole number by another but returns the remainder. Division of numbers with decimal places still requires the division operator (/).

Figure 7 lists the op codes now available as built-in functions.

New H-spec Keywords

Perhaps the biggest changes are in the H-specs. IBM has added new keywords, as well as new values for existing keywords. I’ve summarized these changes in Figure 8. See the ILE RPG for AS/400 Reference for more details.

Miscellaneous Enhancements

Let me mention just three more new features.

The OVERLAY keyword, used in data structure definitions in the D-specs, now supports a new second parameter value: *NEXT. Specifying OVERLAY(name: *NEXT) means that the defined subfield begins at the next available position. In Figure 9, for instance, CustomerNbr begins at position 3 of AccountNbr.

You can now use hexadecimal literals with integers and unsigned data types and either code these literals as initial values or use them in calculation specs.

Last, IBM has changed the internal format of pointer variables. Pointers are now larger and can address terabytes of memory. You don’t have to code pointer variables any differently than in earlier releases.

A Bridge to the Future

I’m glad that IBM continues to enhance RPG, making it more compatible with the rest of the computing world. Although I’m comfortable with the old paradigm of a central computer with terminals, it’s dying fast. The new paradigm has the network as the computer. This release of RPG shows that IBM is helping us RPG programmers move into the future one step at a time, and I’m thankful. I don’t think I could handle a quantum leap.

Reference

ILE RPG for AS/400 Reference (SC09-2508, CD-ROM QB3AGZ03)

C for Ndx = 3 to 9

* Ndx values: 3, 4, 5, 6, 7, 8, 9

C endfor

C

C for Ndx = 3 to 9 by 2

* Ndx values: 3, 5, 7, 9

C endfor

C

C for Ndx = 7 downto 1

* Ndx values: 7, 6, 5, 4, 3, 2, 1

C endfor

C

C for Ndx = 7 downto 1 by 3

* Ndx values: 7, 4, 1

C endfor

Figure 1: The FOR op code governs a counted loop.

D Ndx s 10u 0

C for Ndx = 7 downto 1 by 3

C except dtl

C endfor

Figure 2: This FOR loop fails because the control variable cannot accept a value of -2.

D Column1 s 10

D Column2 s 12

D LineAmt s 7p 2

D InvoiceTotal s 9p 2

C evalr Column2 = %editc(LineAmt: 'J')

C except PrintLine

C evalr Column2 = %editc(InvoiceTotal: 'J': *CURSYM)

C except PrintLine

O e PrintLine

O Column1

O Column2 + 1

Figure 3: The EVALR op code right-adjusts and fills character data.

Length Type Length Range of Values in Bytes in Digits

1 i 3 -128 to 127 1 u 3 0 to 255
2 i 5 -32,768 to 32,767 2 u 5 0 to 65,535
4 i 10 -2,147,483,648 to

2,147,483,647

4 u 10 0 to 4,294,967,295 8 i 20 -9,223,372,036,854,775,808 to 9,223,372,036,854,775,807 8 u 20 0 to

18,446,744,073,709,551,615

Figure 4: RPG supports integers and unsigned data in four lengths.

A* DDS for physical file CUSTOMERS

A UNIQUE

A R CUSTOMER

A ACCOUNT 5 0 TEXT(‘Customer number’)

A NAME 25 TEXT(‘Customer name’)

A CLASS 1 TEXT(‘Customer class’)

A DFT(‘R’)
...(more fields)

A K ACCOUNT

Figure 5: The customer class field has a default value of R.

D Customer e ds extname(Customers) inz(*extdft)

Figure 6: The CLASS subfield is initialized to R.

Op code Function

XFOOT %XFOOT SUBST %SUBST DIV %DIV MVR %REM SCAN %SCAN

Figure 7: These op codes are available as built-in functions.

Keyword Value Description

OPTION *SRCSTMT Debugging statement numbers come from

SEU sequence numbers and generated source ID numbers
OPTION *NODEBUGIO Debug STEP command on I/O operation stops at next calculation spec
CCSID Sets default CCSID for literals, compile-time table/arrray data, and program-described fields for graphic and Unicode data INTPREC Specifies amount of precision in intermediate binary arithmetic
OPENOPT OPENOPT(*INZOFL) causes RPG to turn off associated overflow indicator when opening printer file
THREAD THREAD(*SERIALIZE) allows RPG module to run in multithreaded environment

Figure 8: RPG now supports new keywords, as well as new values for previously supported keywords.

D InputData ds 80

D AccountNbr 8 overlay(InputData: 25)

D CompanyNbr 2 overlay(AccountNbr: 1)

D CustomerNbr 6 overlay(AccountNbr: *next)

Figure 9: Data structure subfields can begin at the next available position of an overlayed field.

Ted Holt is IT manager of Manufacturing Systems Development for Day-Brite Capri Omega, a manufacturer of lighting fixtures in Tupelo, Mississippi. He has worked in the information processing industry since 1981 and is the author or co-author of seven books. 

---

MC Press books written by Ted Holt available now on the MC Press Bookstore.

		Complete CL: Fifth Edition Become a CL guru and fully leverage the abilities of your system. List Price $79.95 Now On Sale
		Complete CL: Sixth Edition Now fully updated! Get the master guide to Control Language programming. List Price $79.95 Now On Sale
		IBM i5/iSeries Primer Check out the ultimate resource and “must-have” guide for every professional working with the i5/iSeries. List Price $99.95 Now On Sale
		Qshell for iSeries Check out this Unix-style shell and utilities command interface for OS/400. List Price $79.95 Now On Sale

Also Read

Programming in ILE RPG - Defining Data Structures, Part I

H and F Position-less Specs

Practical RPG: AI and IBM i